1 REM This file is called cge1.txt
2 REM its based on Dinwiddy and Teal, with adaptation by Mick Common
3 REM primary are labour l and oil r
4 REM sectors are ag 1 and man 2
5 REM normalised price is w=1 on labour
6 REM give it initial p for oil price
7 REM and x1 for gross ag output
8 REM for base case use p = 1.2 and x1 = 1.9
9 REM supplied a1 and a2 are labour coeffs in CRS cd pf
10 A1=0.75
20 A2=0.5
30 L=4
40 R=2
50 A11=0
60 A12=0.4
70 A21=0.2
80 A22=0
90 A=(1-A11)*(1-A22)-A12*A21
100 W=1
110 PRINT "input initial p"
111 INPUT P
120 PRINT "input initial x1"
121 INPUT X1
130 UL1=((P/W)*(A1/(1-A1)))^(1-A1)
140 UL2=((P/W)*(A2/(1-A2)))^(1-A2)
150 UR1=((W/P)*((1-A1)/A1))^(A1)
160 UR2=((W/P)*((1-A2)/A2))^(A2)
170 P1=(1-A22)*((W*UL1)+(P*UR1))
171 P1=(P1+(A21*((W*UL2)+(P*UR2))))/A
180 P2=(1-A11)*((W*UL2)+(P*UR2))
181 P2=(P2+(A12*((W*UL1)+(P*UR1))))/A
190 L1=X1*UL1
200 L2=L-L1
210 X2=L2/UL2
220 R1=X1*UR1
230 R2=X2*UR2
240 Y=(W*(L1+L2))+(P*(R1+R2))
250 C1=Y/(2*P1)
260 C2=Y/(2*P2)
270 X1=((1-A22)*C1+A12*C2)/A
280 IF ABS(R-R1-R2)<0.001 THEN GOTO 350
290 IF(R1+R2)>R THEN P=P+0.001
300 IF(R1+R2)<R THEN P=P-0.001
310 PRINT "p now is"
320 PRINT P
330 PRINT 
340 GOTO 130
350 LPRINT "p1 p2 w p"
360 LPRINT P1, P2, W, P
370 LPRINT
380 LPRINT "x1 x2"
390 LPRINT X1, X2
395 LPRINT
400 LPRINT "l1 l2"
410 LPRINT L1,L2
415 LPRINT
420 LPRINT "r1 r2" 
430 LPRINT R1, R2
440 LPRINT "this output for l and r totals as"
450 LPRINT L, R
455 LPRINT
460 LPRINT "and for lab coeeficients in ag and man as"
470 LPRINT A1, A12
475 LPRINT
480 LPRINT "and for io coeffs a11 a12 a21 a22 as"
490 LPRINT A12, A12, A21, A22
495 LPRINT
500 LPRINT "consumption levels"
510 LPRINT C1, C2
515 LPRINT
520 U=(C1+C2)^0.5
530 LPRINT "utility level"
540 LPRINT U
550 PRINT "check walras"
560 PRINT "ok if zero shows"
570 D=((1-A11)*C2+A21*C1)/A
580 WAL=D-X2
590 PRINT WAL
600 LPRINT